Kako se koristi Excel VLOOKUP funkcija -

Sažetak

VLOOKUP je Excel funkcija za traženje podataka u vertikalno organiziranoj tablici. VLOOKUP podržava približno i točno podudaranje te zamjenske znakove (*?) Za djelomična podudaranja. Vrijednosti pretraživanja moraju se pojaviti u prvom stupcu tablice koji se prosljeđuje u VLOOKUP.

Svrha

Potražite vrijednost u tablici podudaranjem u prvom stupcu

Povratna vrijednost

Podudarna vrijednost iz tablice.

Sintaksa

= VLOOKUP (vrijednost, tablica, col_index, (range_lookup))

Argumenti

vrijednost - vrijednost koju treba potražiti u prvom stupcu tablice.
tablica - tablica iz koje se dohvaća vrijednost.
col_index - stupac u tablici iz kojeg se preuzima vrijednost.
range_lookup - (neobavezno) TRUE = približno podudaranje (zadano). FALSE = točno podudaranje.

Verzija

Excel 2003

Napomene o upotrebi

VLOOKUP je Excel funkcija za dobivanje podataka iz vertikalno organizirane tablice. Vrijednosti pretraživanja moraju se pojaviti u prvom stupcu tablice koji se prosljeđuje u VLOOKUP. VLOOKUP podržava približno i točno podudaranje te zamjenske znakove (*?) Za djelomična podudaranja.

V je za vertikalu

Svrha VLOOKUP-a je dobivanje podataka iz ovako organizirane tablice:

Koristeći broj narudžbe u stupcu B kao vrijednost pretraživanja, VLOOKUP može dobiti korisnički ID, iznos, ime i stanje za bilo koju narudžbu. Na primjer, da biste dobili ime kupca za narudžbu 1004, formula je:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Za vodoravne podatke možete upotrijebiti HLOOKUP, INDEX i MATCH ili XLOOKUP.

VLOOKUP se temelji na brojevima stupaca

Kada koristite VLOOKUP, zamislite da su svi stupci u tablici numerirani, počevši s lijeve strane. Da biste dobili vrijednost iz određenog stupca, navedite odgovarajući broj kao "indeks stupca". Na primjer, indeks stupca za dohvaćanje imena u nastavku je 2:

Prezime i e-adresa mogu se pronaći u stupcima 3 i 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

VLOOKUP izgleda samo ispravno

VLOOKUP može gledati samo udesno. Podaci koje želite preuzeti (vrijednosti rezultata) mogu se pojaviti u bilo kojem stupcu s desne strane vrijednosti pretraživanja:

Ako trebate potražiti vrijednosti s lijeve strane, pogledajte INDEKS i UTAKMICA ili XLOOKUP.

Točno i približno podudaranje

VLOOKUP ima dva načina podudaranja, točni i približni. Ime argumenta koji kontrolira podudaranje je " range_lookup ". Ovo je zbunjujuće ime, jer izgleda da ima neke veze s rasponima stanica poput A1: A10. Zapravo se riječ "raspon" u ovom slučaju odnosi na "raspon vrijednosti" - kada je range_lookup TRUE, VLOOKUP će odgovarati rasponu vrijednosti, a ne točnoj vrijednosti. Dobar primjer za to je korištenje VLOOKUP-a za izračunavanje ocjena.

Važno je razumjeti da je range_lookup zadane vrijednosti TRUE, što znači da će VLOOKUP prema zadanim postavkama koristiti približno podudaranje, što može biti opasno. Postavite range_lookup na FALSE da biste nametnuli točno podudaranje:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Napomena: Također možete unijeti nulu (0) umjesto FALSE za točno podudaranje.

Točno podudaranje

U većini slučajeva vjerojatno ćete htjeti koristiti VLOOKUP u načinu točnog podudaranja. To ima smisla kada imate jedinstveni ključ koji ćete koristiti kao vrijednost pretraživanja, na primjer, naslov filma u ovim podacima:

Formula u H6 za pronalaženje godine , koja se temelji na točnom podudaranju naslova filma, je:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Približno podudaranje

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.